---
name: "dtrace_udp"
section: "4"
platform: "freebsd"
package: "base"
version: "16.0-CURRENT-20261027-61c70dc16a79"
release: "FreeBSD 16.0-CURRENT (2026-10-27)"
platforms: ["freebsd"]
url: "https://new.carta.tech/dtrace_udp"
---

# dtrace\_udp(4)

a DTrace provider for tracing events related to the UDP protocol

## NAME

**dtrace\_udp** – a DTrace provider for tracing events related to the UDP protocol

## SYNOPSIS

**udp:::receive**(*pktinfo\_t \**, *csinfo\_t \**, *ipinfo\_t \**, *udpsinfo\_t \**, *udpinfo\_t \**);

**udp:::send**(*pktinfo\_t \**, *csinfo\_t \**, *ipinfo\_t \**, *udpsinfo\_t \**, *udpinfo\_t \**);

## DESCRIPTION

The DTrace **udp** provider allows users to trace events in the [udp(4)](/udp/4.md) protocol implementation. The **udp:::send**() probe fires whenever the kernel prepares to transmit a UDP packet, and the **udp:::receive**() probe fires whenever the kernel receives a UDP packet, unless the UDP header is incomplete, the destination port is 0, the length field is invalid, or the checksum is wrong. The arguments to these probes can be used to obtain detailed information about the IP and UDP headers of the corresponding packet.

## ARGUMENTS

The *pktinfo\_t* argument is currently unimplemented and is included for compatibility with other implementations of this provider. Its fields are:

- *uintptr\_t* *pkt\_addr*

  Always set to 0.

The *csinfo\_t* argument is currently unimplemented and is included for compatibility with other implementations of this provider. Its fields are:

- *uintptr\_t* *cs\_addr*

  Always set to 0.

- *uint64\_t* *cs\_cid*

  A pointer to the *struct* *inpcb* for this packet, or NULL.

- *pid\_t* *cs\_pid*

  Always set to 0.

The *ipinfo\_t* argument contains IP fields common to both IPv4 and IPv6 packets. Its fields are:

- *uint8\_t* *ip\_ver*

  IP version of the packet, 4 for IPv4 packets and 6 for IPv6 packets.

- *uint32\_t* *ip\_plength*

  IP payload size. This does not include the size of the IP header or IPv6 option headers.

- *string* *ip\_saddr*

  IP source address.

- *string* *ip\_daddr*

  IP destination address.

The *udpsinfo\_t* argument contains the state of the UDP connection associated with the packet. Its fields are:

- *uintptr\_t* *udps\_addr*

  Pointer to the *struct* *inpcb* containing the IP state for the associated socket.

- *uint16\_t* *udps\_lport*

  Local UDP port.

- *uint16\_t* *udps\_rport*

  Remote UDP port.

- *string* *udps\_laddr*

  Local IPv4 or IPv6 address.

- *string* *udps\_raddr*

  Remote IPv4 or IPv6 address.

The *udpinfo\_t* argument is the raw UDP header of the packet, with all fields in host order. Its fields are:

- *uint16\_t* *udp\_sport*

  Source UDP port.

- *uint16\_t* *udp\_dport*

  Destination UDP port.

- *uint16\_t* *udp\_length*

  Length of the UDP header and payload, in bytes.

- *uint16\_t* *udp\_checksum*

  A checksum of the UDP header and payload, or 0 if no checksum was calculated.

- *struct* *udphdr* *\*udp\_hdr*

  A pointer to the raw UDP header.

## FILES

- */usr/lib/dtrace/udp.d*

  DTrace type and translator definitions for the **udp** provider.

## EXAMPLES

The following script counts transmitted packets by destination port.

```
udp:::send
{
        @num[args[4]->udp_dport] = count();
}
```

This script will print some details of each UDP packet as it is sent or received by the kernel:

```
#pragma D option quiet
#pragma D option switchrate=10Hz
dtrace:::BEGIN
{
        printf(" %10s %36s    %-36s %6s\n", "DELTA(us)", "SOURCE",
            "DEST", "BYTES");
        last = timestamp;
}
udp:::send
{
        this->elapsed = (timestamp - last) / 1000;
        self->dest = strjoin(strjoin(args[2]->ip_daddr, ":"),
             lltostr(args[4]->udp_dport));
        printf(" %10d %30s:%-5d -> %-36s %6d\n", this->elapsed,
            args[2]->ip_saddr, args[4]->udp_sport,
            self->dest, args[4]->udp_length);
        last = timestamp;
}
udp:::receive
{
        this->elapsed = (timestamp - last) / 1000;
        self->dest = strjoin(strjoin(args[2]->ip_saddr, ":"),
             lltostr(args[4]->udp_sport));
        printf(" %10d %30s:%-5d <- %-36s %6d\n", this->elapsed,
            args[2]->ip_daddr, args[4]->udp_dport,
            self->dest, args[4]->udp_length);
        last = timestamp;
}
```

## COMPATIBILITY

This provider is compatible with the **udp** provider in Solaris.

## SEE ALSO

[dtrace(1)](/dtrace/1.md), [dtrace\_ip(4)](/dtrace_ip/4.md), [dtrace\_sctp(4)](/dtrace_sctp/4.md), [dtrace\_tcp(4)](/dtrace_tcp/4.md), [dtrace\_udplite(4)](/dtrace_udplite/4.md), [udp(4)](/udp/4.md), [SDT(9)](/SDT/9.md)

## HISTORY

The **udp** provider first appeared in FreeBSD 10.0.

## AUTHORS

This manual page was written by Mark Johnston ⟨*markj@FreeBSD.org*⟩.