---
name: "Mojo::ByteStream"
section: "3pm"
platform: "linux"
package: "libmojolicious-perl"
version: "9.39+dfsg-1"
release: "Debian 13 (Trixie)"
platforms: ["linux"]
url: "https://new.carta.tech/Mojo::ByteStream"
---

# Mojo::ByteStream(3pm)

ByteStream

## NAME

Mojo::ByteStream - ByteStream

## SYNOPSIS

```
  use Mojo::ByteStream;
  # Manipulate bytestream
  my $stream = Mojo::ByteStream->new('foo_bar_baz');
  say $stream->camelize;
  # Chain methods
  my $stream = Mojo::ByteStream->new('foo bar baz')->quote;
  $stream = $stream->unquote->encode('UTF-8')->b64_encode('');
  say "$stream";
  # Use the alternative constructor
  use Mojo::ByteStream qw(b);
  my $stream = b('foobarbaz')->b64_encode('')->say;
```

## DESCRIPTION

Mojo::ByteStream is a scalar-based container for bytestreams that provides a more friendly API for many of the functions in Mojo::Util.

```
  # Access scalar directly to manipulate bytestream
  my $stream = Mojo::ByteStream->new('foo');
  $$stream .= 'bar';
```

## FUNCTIONS

Mojo::ByteStream implements the following functions, which can be imported individually.

### b

```
  my $stream = b('test123');
```

Construct a new scalar-based Mojo::ByteStream object.

## METHODS

Mojo::ByteStream implements the following methods.

### b64\_decode

```
  $stream = $stream->b64_decode;
```

Base64 decode bytestream with "b64\_decode" in Mojo::Util.

### b64\_encode

```
  $stream = $stream->b64_encode;
  $stream = $stream->b64_encode("\n");
```

Base64 encode bytestream with "b64\_encode" in Mojo::Util.

```
  # "Zm9vIGJhciBiYXo="
  b('foo bar baz')->b64_encode('');
```

### camelize

```
  $stream = $stream->camelize;
```

Camelize bytestream with "camelize" in Mojo::Util.

### clone

```
  my $stream2 = $stream->clone;
```

Return a new Mojo::ByteStream object cloned from this bytestream.

### decamelize

```
  $stream = $stream->decamelize;
```

Decamelize bytestream with "decamelize" in Mojo::Util.

### decode

```
  $stream = $stream->decode;
  $stream = $stream->decode('iso-8859-1');
```

Decode bytestream with "decode" in Mojo::Util, defaults to using `"UTF-8"`.

```
  # "♥"
  b('%E2%99%A5')->url_unescape->decode;
```

### encode

```
  $stream = $stream->encode;
  $stream = $stream->encode('iso-8859-1');
```

Encode bytestream with "encode" in Mojo::Util, defaults to using `"UTF-8"`.

```
  # "%E2%99%A5"
  b('♥')->encode->url_escape;
```

### gunzip

```
  $stream = $stream->gunzip;
```

Uncompress bytestream with "gunzip" in Mojo::Util.

### gzip

```
  stream = $stream->gzip;
```

Compress bytestream with "gzip" in Mojo::Util.

### hmac\_sha1\_sum

```
  $stream = $stream->hmac_sha1_sum('passw0rd');
```

Generate HMAC-SHA1 checksum for bytestream with "hmac\_sha1\_sum" in Mojo::Util.

```
  # "7fbdc89263974a89210ea71f171c77d3f8c21471"
  b('foo bar baz')->hmac_sha1_sum('secr3t');
```

### html\_unescape

```
  $stream = $stream->html_unescape;
```

Unescape all HTML entities in bytestream with "html\_unescape" in Mojo::Util.

```
  # "%3Chtml%3E"
  b('<html>')->html_unescape->url_escape;
```

### humanize\_bytes

```
  $stream = $stream->humanize_bytes;
```

Turn number of bytes into a simplified human readable format for bytestream with "humanize\_bytes" in Mojo::Util.

### md5\_bytes

```
  $stream = $stream->md5_bytes;
```

Generate binary MD5 checksum for bytestream with "md5\_bytes" in Mojo::Util.

### md5\_sum

```
  $stream = $stream->md5_sum;
```

Generate MD5 checksum for bytestream with "md5\_sum" in Mojo::Util.

### new

```
  my $stream = Mojo::ByteStream->new('test123');
```

Construct a new scalar-based Mojo::ByteStream object.

### punycode\_decode

```
  $stream = $stream->punycode_decode;
```

Punycode decode bytestream with "punycode\_decode" in Mojo::Util.

### punycode\_encode

```
  $stream = $stream->punycode_encode;
```

Punycode encode bytestream with "punycode\_encode" in Mojo::Util.

### quote

```
  $stream = $stream->quote;
```

Quote bytestream with "quote" in Mojo::Util.

### say

```
  $stream = $stream->say;
  $stream = $stream->say(*STDERR);
```

Print bytestream to handle and append a newline, defaults to using `"STDOUT"`.

### secure\_compare

```
  my $bool = $stream->secure_compare($str);
```

Compare bytestream with "secure\_compare" in Mojo::Util.

### sha1\_bytes

```
  $stream = $stream->sha1_bytes;
```

Generate binary SHA1 checksum for bytestream with "sha1\_bytes" in Mojo::Util.

### sha1\_sum

```
  $stream = $stream->sha1_sum;
```

Generate SHA1 checksum for bytestream with "sha1\_sum" in Mojo::Util.

### size

```
  my $size = $stream->size;
```

Size of bytestream.

### slugify

```
  $stream = $stream->slugify;
  $stream = $stream->slugify($bool);
```

Generate URL slug for bytestream with "slugify" in Mojo::Util.

### split

```
  my $collection = $stream->split(',');
  my $collection = $stream->split(',', -1);
```

Turn bytestream into Mojo::Collection object containing Mojo::ByteStream objects.

```
  # "One,Two,Three"
  b("one,two,three")->split(',')->map('camelize')->join(',');
  # "One,Two,Three,,,"
  b("one,two,three,,,")->split(',', -1)->map('camelize')->join(',');
```

### tap

```
  $stream = $stream->tap(sub {...});
```

Alias for "tap" in Mojo::Base.

### term\_escape

```
  $stream = $stream->term_escape;
```

Escape POSIX control characters in bytestream with "term\_escape" in Mojo::Util.

```
  # Print binary checksum to terminal
  b('foo')->sha1_bytes->term_escape->say;
```

### to\_string

```
  my $str = $stream->to_string;
```

Stringify bytestream.

### trim

```
  $stream = $stream->trim;
```

Trim whitespace characters from both ends of bytestream with "trim" in Mojo::Util.

### unindent

```
  $stream = $stream->unindent;
```

Unindent bytestream with "unindent" in Mojo::Util.

### unquote

```
  $stream = $stream->unquote;
```

Unquote bytestream with "unquote" in Mojo::Util.

### url\_escape

```
  $stream = $stream->url_escape;
  $stream = $stream->url_escape('^A-Za-z0-9\-._~');
```

Percent encode all unsafe characters in bytestream with "url\_escape" in Mojo::Util.

```
  # "%E2%98%83"
  b('☃')->encode->url_escape;
```

### url\_unescape

```
  $stream = $stream->url_unescape;
```

Decode percent encoded characters in bytestream with "url\_unescape" in Mojo::Util.

```
  # "<html>"
  b('%3Chtml%3E')->url_unescape->xml_escape;
```

### with\_roles

```
  my $new_class = Mojo::ByteStream->with_roles('Mojo::ByteStream::Role::One');
  my $new_class = Mojo::ByteStream->with_roles('+One', '+Two');
  $stream       = $stream->with_roles('+One', '+Two');
```

Alias for "with\_roles" in Mojo::Base.

### xml\_escape

```
  $stream = $stream->xml_escape;
```

Escape only the characters `"&"`, `"<"`, `">"`, `"""` and `"'"` in bytestream with "xml\_escape" in Mojo::Util.

### xor\_encode

```
  $stream = $stream->xor_encode($key);
```

XOR encode bytestream with "xor\_encode" in Mojo::Util.

```
  # "%04%0E%15B%03%1B%10"
  b('foo bar')->xor_encode('baz')->url_escape;
```

## OPERATORS

Mojo::ByteStream overloads the following operators.

### bool

```
  my $bool = !!$bytestream;
```

Always true.

### stringify

```
  my $str = "$bytestream";
```

Alias for "to\_string".

## SEE ALSO

Mojolicious, Mojolicious::Guides, \<https://mojolicious.org\>.