---
name: "DBIx::Class::Helper::Row::ToJSON"
section: "3pm"
platform: "linux"
package: "libdbix-class-helpers-perl"
version: "2.037000-1"
release: "Debian 13 (Trixie)"
platforms: ["linux"]
url: "https://new.carta.tech/DBIx::Class::Helper::Row::ToJSON"
---

# DBIx::Class::Helper::Row::ToJSON(3pm)

Remove the boilerplate from your TO\_JSON functions

## NAME

DBIx::Class::Helper::Row::ToJSON - Remove the boilerplate from your TO\_JSON functions

## SYNOPSIS

```
 package MyApp::Schema::Result::KittenRobot;
 use parent 'DBIx::Class::Core';
 __PACKAGE__->load_components(qw{Helper::Row::ToJSON});
 __PACKAGE__->table('KittenRobot');
 __PACKAGE__->add_columns(
    id => {
       data_type         => 'integer',
       is_auto_increment => 1,
    },
    kitten => {
       data_type         => 'integer',
    },
    robot => {
       data_type         => 'text',
       is_nullable       => 1,
    },
    your_mom => {
       data_type         => 'blob',
       is_nullable       => 1,
       is_serializable   => 1,
    },
 );
 1;
```

This helper adds a JSON method like the following:

```
 sub TO_JSON {
    return {
       id       => $self->id,
       kitten   => $self->kitten,
       # robot  => $self->robot,    # <-- doesn't serialize text columns
       your_mom => $self->your_mom, # <-- normally wouldn't but explicitly
                                    #     asked for in the column spec above
    }
 }
```

## METHODS

### \_is\_column\_serializable

```
 $self->_is_column_serializable('kitten')
```

returns true if a column should be serializable or not.  Currently this marks everything as serializable unless `"is_serializable"` is set to false, or `"data_type"` is a `"blob"`, `"text"`, or `"ntext"` columns.  If you wanted to only have explicit serialization you might override this method to look like this:

```
 sub _is_column_serializable {
    my ( $self, $column ) = @_;
    my $info = $self->column_info($column);
    return defined $info->{is_serializable} && $info->{is_serializable};
 }
```

### serializable\_columns

```
 $self->serializable_columns
```

simply returns a list of columns that TO\_JSON should serialize.

### TO\_JSON

```
 $self->TO_JSON
```

returns a hashref representing your object.  Override this method to add data to the returned hashref:

```
 sub TO_JSON {
    my $self = shift;
    return {
       customer_name => $self->customer->name,
       %{ $self->next::method },
    }
 }
```

### unserializable\_data\_types

```
 $self->unserializable_data_types
```

Simply returns a hashref of data types that TO\_JSON should not serialize. Defaults to `"blob"`, `"text"`, or `"ntext"`.

If you wanted to allow serialization of text data types, you might override this method to look like this:

```
 sub unserializable_data_types {
    return {
       blob  => 1,
       ntext => 1,
    };
 }
```

## AUTHOR

Arthur Axel "fREW" Schmidt \<frioux+cpan@gmail.com\>

## COPYRIGHT AND LICENSE

This software is copyright (c) 2024 by Arthur Axel "fREW" Schmidt.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.